TEMPLATE = app
DESTDIR  = ../bin
CONFIG  += qt opengl xml warn_on console debug_and_release thread
QT *= opengl xml


CONFIG(debug, debug|release) {
	TARGET   = raymini_d
} else {
	TARGET   = raymini
}
HEADERS = Window.h \
		  GLViewer.h \
		  QTUtils.h \
		  Vertex.h \
		  Triangle.h \
		  Mesh.h \
		  BoundingBox.h \
		  Material.h \
		  Object.h \
		  Light.h \
		  Scene.h \
		  RayTracer.h \
		  Ray.h \
		  Vec3D.h \
		  Color.h \
		  KdTree.h \
		  Random.h

SOURCES = Window.cpp \
		  GLViewer.cpp \
		  QTUtils.cpp \
		  Vertex.cpp \
		  Triangle.cpp \
		  Mesh.cpp \
		  BoundingBox.cpp \
		  Material.cpp \
		  Object.cpp \
		  Light.cpp \
		  Scene.cpp \
		  RayTracer.cpp \
		  Ray.cpp \
		  Main.cpp \
		  KdTree.cpp \
		  Random.cpp


win32 {
	DEFINES += NOMINMAX
	INCLUDEPATH += D:/Libs/libQGLViewer-2.3.17 \
			   D:/Libs/glew/include \
			   D:/Libs/assimp/include
	LIBS += -L"D:/Libs/libQGLViewer-2.3.17/lib" \
		-L"D:/Libs/glew/lib" \
		-L"D:/Libs/assimp/lib"

	QMAKE_CXXFLAGS+= -openmp
	#QMAKE_LFLAGS +=  -openmp

	CONFIG(debug, debug|release) {
		LIBS += -lQGLViewerd2 -lglew32d -lassimp
	} else {
		LIBS += -lQGLViewer2 -lglew32 -lassimpD
	}
}
unix {
	INCLUDEPATH += ../assimp/include
	QMAKE_CXXFLAGS+= -fopenmp
	QMAKE_LFLAGS+= -fopenmp
	LIBS += ../assimp/lib/gcc/libassimp.a
	LIBS += -lGLEW \
			-lqglviewer-qt4
}

MOC_DIR = tmp
OBJECTS_DIR = tmp

